'==========================================================================
'
'
' NAME: <ServiceAccount.vbs>
'
' AUTHOR: Ed Wilson , MS
' DATE  : 5/3/2006
'
' COMMENT: <Uses the startName property from win32_service>
'1. filter out services using localSystem account.
'==========================================================================

Option Explicit 
'On Error Resume Next
dim strComputer			'target computer
dim wmiNS						'target wmi name space
dim wmiQuery				'the WMI query
dim objWMIService		'sWbemservices object
dim colItems				'sWbemObjectSet object
dim objItem					'sWbemObject

strComputer = "."
wmiNS = "\root\cimv2"
wmiQuery = "Select StartName, started from win32_service" &_
	" where startName <> 'localSystem'"
Set objWMIService = GetObject("winmgmts:\\" & strComputer & wmiNS)
Set colItems = objWMIService.ExecQuery(wmiQuery)

For Each objItem in colItems
    Wscript.Echo objItem.name, VbCrLf & vbTab &_
    objItem.StartName & vbTab & "Running: " & objItem.Started   
Next